home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Magnum One
/
Magnum One (Mid-American Digital) (Disc Manufacturing).iso
/
d27
/
dltobs.arc
/
DLTOBS.ASM
next >
Wrap
Assembly Source File
|
1991-12-04
|
5KB
|
71 lines
/* Program - DLTPGMOBS */ ;
/* Written - 10/15/86 */ ;
/* Author - R. Cozzi, Jr. */ ;
/* ----------------------------------------------------- */ ;
/* Purpose: -------------------------------------------- */ ;
/* -------- To remove a program's observability. * */ ;
/* * Thus, deleting the program's ability * */ ;
/* * to be debugged. * */ ;
/* * * */ ;
/* Modification Log: --------------------------------- */ ;
/* ----------------------------------------------------- */ ;
/* Date By Description */ ;
/* -------- ---------- --------------------------------- */ ;
/* */ ;
/* ----------------------------------------------------- */ ;
;
DCL SPCPTR P.PROGRAM PARM ;
DCL DD PROGRAM CHAR(20) BAS(P.PROGRAM) ;
DCL DD PGMNAM CHAR(10) DEF(PROGRAM) POS(1) ;
DCL DD PGMLIB CHAR(10) DEF(PROGRAM) POS(11) ;
DCL OL PLIST (P.PROGRAM) PARM EXT ;
;
DCL SYSPTR .PGMPTR /* Pointer to program name */ ;
DCL SYSPTR .LIBPTR /* Pointer to library name */ ;
;
/* Resolve System Pointer template to program name */ ;
DCL DD .PGMTEMPL CHAR(34) ;
DCL DD * CHAR(2) DEF(.PGMTEMPL) POS(1) INIT(X'0201') ;
DCL DD .PGMNAME CHAR(30) DEF(.PGMTEMPL) POS(3) INIT ;
DCL DD * CHAR(2) DEF(.PGMTEMPL) POS(33) INIT(X'0000') ;
;
/* Resolve System Pointer template to program name */ ;
DCL DD .LIBTEMPL CHAR(34) ;
DCL DD * CHAR(2) DEF(.LIBTEMPL) POS(1) INIT(X'0401') ;
DCL DD .LIBNAME CHAR(30) DEF(.LIBTEMPL) POS(3) INIT ;
DCL DD * CHAR(2) DEF(.LIBTEMPL) POS(33) INIT(X'0800') ;
;
DCL CON *BLANKS CHAR(1) INIT(X'40') ;
DCL CON *BLANK CHAR(1) INIT(X'40') ;
;
ENTRY * (PLIST) EXT ;
;
/* Put program name into pointer template */ ;
CPYBLAP .PGMNAME,PGMNAM,*BLANKS ;
;
/* If %sst(&PGM 11 10) = *BLANKS or *LIBL then DO */ ;
;
CMPBLAP(B) PGMLIB,C'*LIBL',*BLANKS/EQ(.GETPGM) ;
CMPBLAP(B) PGMLIB,*BLANKS,*BLANKS/EQ(.GETPGM) ;
CPYBLAP .LIBNAME,PGMLIB,*BLANKS ;
RSLVSP .LIBPTR,.LIBTEMPL,*,* /* Resolve to library */ ;
RSLVSP .PGMPTR,.PGMTEMPL,.LIBPTR,* ;
B .DLTPGMOBS /* Goto delete program observability */ ;
;
/* ENDDO */ ;
/* ELSE DO */ ;
;
.GETPGM: /* Resolve to Program.*LIBL */ ;
RSLVSP .PGMPTR,.PGMTEMPL,*,* ;
;
/* ENDDO */ ;
;
.DLTPGMOBS: ;
DELPGOBS .PGMPTR /* Delete program observability */ ;
;
.ENDPGM: ;
;
DEACTPG * /* Terminate the program */ ;
RTX * /* Return to caller */ ;
PEND ;